!
! Case 1, rho = 2700 kg/m^3
! Total simulation time for dynamic impact =  4.5E-5
!
/BATCH  
/COM,ANSYS RELEASE  5.7.1  UP20010418       13:14:04    04/28/2004
/input,menust,tmp     ,  ,,,,,,,,,,,,,,,,1  
/GRA,POWER
/GST,ON
/PLO,INFO,3
/COL,PBAK,ON,1,BLUE 
!* ---  1. File - Change Title
/TITLE,Aluminum Bar Impacting A Rigid Boundary (VMC8)   
!* ---  2. PlotCtrls > Device Option: Turn on the vector mode
/SHOW,X11   
/DEVICE,VECTOR,1
/DEVICE,DITHER,1
/REPLOT 
!*  
! --- 3. Type the command "/UNITS, SI", press enter
/UNITS, SI  
! -- 4. Parameters - Scalar Parameters
! 
! Material parameters
*SET,RHO,2700
*SET,DTIME,4.5E-5
!
*SET,EE,70E9
!
*SET,RAD,0.00381     	! BAR RADIUS [m]
*SET,L,0.02347  	! BAR LENGTH
*SET,DI,0.0001   	! INTERFACE BETWEEN THE BAR AND THE WALL
*SET,VEL,478.0  	! INITIAL VELOCITY [M/SEC]
*SET,CVEL,(EE/RHO)**0.5   !  ELASTIC WAVE PROPAGATION SPEED = sqrt(E/rho)
*SET,TEL,(RAD/4)/CVEL    ! TIME STEP INCREMENT (4 ELEMENTS ALONG RADIUS)
*SET,NLS,NINT(1.1*(DTIME/TEL))  ! MINIMUM NUMBER OF SUBSTEPS FOT TIME=DTIME
!
!*  
! -- 5.  Use Solid Quad 2node 82 Element
/PREP7
ET,1,PLANE82
!*  
! -- 6. Element Type, Add/Edit/Delete, Options, switch Element behavior to axisymmetric
KEYOPT,1,3,1
! -- 7a. Material Model - linear - elestic -  isotropic
! -- 7b. Material Model - density
! -- 7c. Material Model - Nonlinear - Inelastic - Isotropic Hardening - Bilinear - 
MP,EX,1,EE                    ! ELASTIC MODULUS [Pa]
MP,NUXY,1,0.3
MP,DENS,1,RHO                  ! DENSITY (KG/M^3)
TB,BISO,1                       ! BILINEAR ISOTROPIC HARDENING
TBDAT,1,420E6,100E6             ! YEILD STRESS [Pa], TANGENT MODULUS [Pa] (The slope after the yield)
! -- 8. Geometry
! -- 8a. 4 key points
!
K,1,0,DI                        ! SOLID MODEL 
K,2,RAD,DI
K,3,RAD,(DI+L)
K,4,0,(DI+L)
! -- 8b. Draw Lines
L,1,2
L,3,4
L,1,4
L,2,3
! -- 8c  Use 4 equal divisions in x direction
!         Use 12 non-equal divisions in y direction with a spacing ratio = 3 Last/First
FLST,5,2,4,ORDE,2
FITEM,5,1
FITEM,5,-2
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
!*
LESIZE,_Y1, , ,4, , , , ,1
!*
FLST,5,2,4,ORDE,2
FITEM,5,3
FITEM,5,-4
CM,_Y,LINE
LSEL, , , ,P51X
CM,_Y1,LINE
CMSEL,,_Y
!*
LESIZE,_Y1, , ,12,3, , , ,1
!*
! 8d. Create an area
!
FLST,2,4,4
FITEM,2,1
FITEM,2,4
FITEM,2,2
FITEM,2,3
AL,P51X
!
! 9 Mesh 
!*
CM,_Y,AREA
ASEL, , , ,       1
CM,_Y1,AREA
CHKMSH,'AREA'
CMSEL,S,_Y
!*
MSHKEY,1
AMESH,_Y1
MSHKEY,0
!*
CMDELE,_Y
CMDELE,_Y1
CMDELE,_Y2
!*
EPLOT
!
! -- 10. Boundary conditions
!
! Loads-Apply-Displacement-On Nodes
! First, select all nodes at x=0
! Set UX=0 due to symmetry
NSEL,S,LOC,X,0 
D,ALL,UX                          
! Next Select the node number on top of the
! symmetry line, and find the nude number,
! save as NTOP
! Result NTOP = 34
!
NSEL,S,LOC,X,0                 
NSEL,R,LOC,Y,L+DI
! 
! Parameter - Get scalar data - Model data/For selected set -OK
!      - Name=NTOP/Current Node Set/Lowest Node number - OK
*GET,NTOP,NODE,,NUM,MIN   
! Select - Everything
NSEL,ALL
!
! Extract node number at location (0.,0.,0.) - NO GUI
!
NBOT=NODE(0,0,0) 
NSEL,S,,,NBOT
ESLN,S
! Obtain the element number associated with NBOT
*GET,EBOT,ELEM,,NUM,MIN
!
! Also set the node number on the bottom of the symmetry line to NBOT
! NBOT = 1
! The element number attached to NBOT node to EBOT
! EBOT = 1
!
NSEL,ALL
ESEL,ALL
SAVE
FINISH
!
!
/SOLU
! 
!  Preprocessor-Loads-Analysis Type - New Analysis: Check transient
ANTYPE,TRANS    ! Set analysis type to transient, 
!
! Specifies the Newton-Raphson options in a static or full transient analysis.
! Preprocessor-Loads-Analysis Options: Turn on LArge deform effects,
!                                      Check Newton-Raphson option = Full N-R
!  
NROPT,FULL
NLGEOM,ON     !  Include Large Deformation effects
!
! Solution-Sol'n Controls-basic 
AUTOTS,ON   ! Use automatic time stepping
! 
! Turn off the real time integration for the initial load step
! Solution-Sol'n Controls - transient: 
TIMINT,OFF                      ! STATIC LOAD STEP - DEFINE INITIAL VELOCITY    
! 
T1=DI/VEL                       ! TIME INCREMENT 
!
! Set the time at the end of the initial (static) load step.
! Solution-Sol'n Controls - Basic
! Set Time at end of load step = T1
! Check time increment, set time step size = T1
TIME,T1
DELTIM,T1                      
!
! Select all nodes at bottoms
NSEL,S,LOC,Y,DI
! Set deformation in y to -DI
! Solution - Load - Apply - Displacement - Pick all - Lab2=UY, Value=-DI
D,ALL,UY,-DI
NSEL,ALL 
! Sets the key to terminate an analysis: 
! 2 means "to terminate the analysis, but does not exit the program execution, if the solution fails to converge.
! Solution-Sol'n Controls- advanced nl
! Set termination criteria to "Terminate but do not exit"
NCNV,2
! Sets convergence values for nonlinear analyses.
! Solution-Sol'n Controls- Nonlinear - Set convergence criteria - Replace 
! Select Structural/Displacement U, Value = 1, Toler = 0.001
!
CNVTOL,U,1,0.001
! Controls the solution printout: This print the results to screen. Suppress all.
!  Preprocessor-Loads-Load step options - Output Ctrls - Solution Printout Controls 
!   Set Item = All items, Freq = None
OUTPR,ALL,NONE
! Controls the solution data written to the database.
!  Solution-Sol'n Controls - Basic: Frequency - Write every Nth substep 
!  with N= 10
OUTRES,ALL,10 
! Solution - Write Load step
LSWRITE,1,
! Solve the static load step
SOLVE                           ! LOAD STEP 1 - STATIC
! Switch on the time integration
!  Solution-Sol'n Controls - transient:  Turn back on transient effects
TIMINT,ON                     
!  Specifies the maximum number of equilibrium iterations for each substep in nonlinear analysis
!  Solution-Sol'n Controls - Nonlinear - Equilibrium iterations
NEQIT,40
! Sets convergence values for nonlinear analyses.
! Solution-Sol'n Controls- Nonlinear - Set convergence criteria
!
CNVTOL,U   
! Structural/Force Value (typical value) = 0.01, TOLER = 0.001
CNVTOL,F,0.01,0.001
! Specifies the number of substeps to be taken this load step
!  Solution-Sol'n Controls - Basic: 
!     Set time at end of the load step = T1+DTIME
!   Check Number of substeps
!   set Number of substeps = NSL
!   Max no. of substeps = 10*NLS
!   Min no. of substeps = NSL
TIME,(T1+DTIME)
NSUBSTEP,NLS,10*NLS,NLS
!
! Write Load Step, set Load step file number n = 2
LSWRITE,2,
! Set Redirects text output to file scratch
! tility Menu-File-Switch Output to-File
/OUT,SCRATCH
! Solve the dynamic load step
SOLVE                           ! LOAD STEP 1 - DYNAMIC
! Redirects text output back to default screen
/OUT
! Save all current data base information
SAVE
!
FINISH
!
/POST1
! Bring in last set
SET,LAST
! Show real displacement (no magnification)
! Utility Menu-PlotCtrls-Style-Displacement Scaling 
/DSCAL,1,1
PLDISP                          ! PLOT DEFORMED SHAPE
! 
! Assign a new variable DYTP the value of displacement at node NTOP
! Parameters - Get Scalar Data - Results Data / Nodal Results
! Set Name = DYTP, Node number = NTOP, DOF Solution / UY
!
*GET,DYTP,UY,NTOP               ! NODAL DISPLACEMENT OF TOP NODE
LF=(L+DI)+DYTP                  ! DEFORMED LENGTH
LFA1=LF
LFA2=LF/(L*0.562)
! Note 0.562 is the experimental value of the relative length
! 1.319cm/2.347 cm = 0.562
! Lists the value of LF1 and LF2
*STATUS,LF1
*STATUS,LF2
FINISH
! Time history post analysis
!
/POST26
! Display full grid: PlotCtrls-Style-Graphs-Modify Grid
!
/GRID,1
! Specifies the X variable to be displayed
! TimeHist Postpro-Settings-Graph: Check Single variable and set variable no. = 1
XVAR,1
! 
! Specifies nodal data to be stored from the results file
! TimeHist Postpro-Define Variables - Add 
! Adds variables
! Time History-Graph Variables
NSOL,2,NTOP,U,Y                 ! DISPLACEMENT OF FREE END NODE
ESOL,3,EBOT,NBOT,EPPL,EQV       ! EQUIVALENT PLASTIC STRAIN
! TimeHist Postpro-Math Operations-Add
! Set IR = 2, FACTA = -1, IA =2
! Basically multiply the second variable by (-1)
ADD,2,2,,,DISP,,,-1
! PlotCtrls-Style-Graphs-Modify Axes
/AXLAB,X,TIME [SEC]
/AXLAB,Y,FREE END DISPLACEMENT [M]
! Plot a variable or variables in the form of a graph.
! TimeHist Postpro-Graph Variables 
PLVAR,2                         ! PLOT DISPLACEMENT VS. TIME
/AXLAB,Y,EPPL-EQV AT NODE 1       
PLVAR,3                         ! PLOT PLASTIC STRAIN
FINISH