/BATCH  
/COM,ANSYS RELEASE  5.7.1  UP20010418       17:40:41    10/26/2005
/input,menust,tmp     ,  ,,,,,,,,,,,,,,,,1  
/GRA,POWER
/GST,ON
/PLO,INFO,3
/COL,PBAK,ON,1,BLUE 
!*
!* Step 1: Specify the title
!* File > Change Title 
/TITLE,Transient Displacements in a suddenly stopped moving bar  
!*
!* Step 2: Specify element type
!* Preprocessor>Element Type>Add/Edit/Delete 
/PREP7  
!*  
ET,1,LINK1  
!*
!* Step 3: Define Real constant - area
!* Preprocessor>Real Constants>Add/Edit/Delete
R,1,1.0,0., 
!*  
!* Step 4: Define material properties:  modulus and density
!* Preprocessor>Material Props>Material Models
MP,EX,1,30e6   
MP,DENS,1,0.00073  
!
!* Step 5: define two end nodes of the bar
!* Preprocessor>Create>Nodes>In Active CS
N,1,0,0,0,,,,
N,17,10000,0,0,,,,  
!*  
!* Step 6: Fill nodes in between
!* Preprocessor>Create>Nodes>Fill between Nds
FILL,1,17,15, , ,1,1,1, 
!*  
!* Step 7: Create first element with node 1 and node 2
!*  Preprocessor>Create>Elements>Through nodes
E,1,2  
!*
!* Step 8: create more elements by copying
!* Preprocessor>Modeling/Copy>Elements/Auto Numbered 
EGEN,16,1,1
FINISH
!*
!* Step 9: Analysis type = Transient, reduced method, No damping
!* Solution > Analysis Type - New Analysis (select transient, then reduced)
/SOLU   
!*
ANTYPE,4
TRNOPT,REDUC
LUMPM,0	! Use the element-dependent default mass matrix (default)
!*
!* Solution > Analysis Options (select "ignore" damping)
TRNOPT,REDUC, ,NODAMP
PSTRES,0	! No prestress (default)
!*
FINISH
!*
!*
/PREP7
!*
!* Step 10: Defined master degree of freedom for reduced analysis (all 17 nodes)
!* Preprocessor>Loads>Master DOFs>Define 
! (set 1st degree of freedom = UX)
FLST,2,17,1,ORDE,2
FITEM,2,1
FITEM,2,-17
M,P51X,UX, , ,
!*
!* Step 11: Define node 20 as ground node and define the gap condition
!* The location is irrelevant
!* It does not matter where Node 20 is located.
N,20,2.0,0.,0.,,,,
!* Preprocessor>Loads>Dynamic Gap Cond>Define 
!* pick node 1 and node 20, set STIF=2E7, GAP=0.64
GP,1,20,FX,3E7,.64          ! GAP CONDITION
!* Step 11b: I added another node, node 21 and a 
!* gap condition to prevent the negative movement for node 1
!* so I can run the case for longer time
N,21,-2.0,0.,0.,,,,
!* Preprocessor>Loads>Dynamic Gap Cond>Define
!* Note the order of nodes, node 21 first then node 1.
GP,21,1,FX,3E7,.64          ! GAP CONDITION
!*
FINISH
!*
/SOLU
!* Step 12: Time step size = 0.0001
!* Solution>Load Step Opts - Time/Frequency>Time - Time step
!*  Enter 0.0001 for time step size
!*  Also check KBC = Stepped
DELTIM,.0001                ! ITS DEFINITION
KBC,1                       ! STEP BOUNDARY CONDITION
!*
!* START THE STATIC LOAD STEP ================================================
!* Step 13: Set zero y-displacement
!*  Solution > Loads-Apply > Displacement > On Nodes > 
!* Pick UY, set value=0, and apply
!* pick all nodes
D,ALL,UY
!* Step 14: Set zero force
!*  Solution > Loads-Apply > Force/Moment > On Nodes >
!* Check "min,max,inc" under "For keyboard entry"
!* Type 1,17,1, return, and "OK", Then “cancel”
F,1,FX,,,17                 ! DEFINE NULL FORCES ON ALL BAR NODES
!* Step 15: Solve the static load step
SOLVE
!* 
!* START THE SECOND LOAD STEP FROM t=0 to t=0.0004 =============================
!* Step 16: Specify time step size
!* Solution>Load Step Opts - Time/Frequency>Time - Time step
!* Set TIME = 0.0004, DELTIM = 0.0001 unchanged
TIME,.0004
!* 
!* Step 17: Apply the total force load = v0 mass / 0.0004 = 1,825,000 lbf
!*  Solution > Loads-Apply > Force/Moment > On Nodes >
!* On the two end nodes, node 1 and node 17
!* mag = 1,825,000/16*0.5
F,1,FX,57031.25,,17,16     !FORCES REQUIRED TO ACHIEVE INITIAL VELOCITY
!* On the 15 internal nodes
!* mag = 1,825,000/16
F,2,FX,114062.5,,16
!* Step 18: Solve the second load step
SOLVE
!*
!* START THE THIRD LOAD STEP FROM t=0.004 to t=0.40 =============================
!* Step 19: Set end time to 0.40
TIME,.40
!* Step 20: Remove force load
F,1,FX,,,17                 ! REMOVE FORCES ("COAST")
!* Step 21: Solve the third load step
SOLVE
!* Step 22: Main Menu - Finish - This is very important so the result
!* data is saved to VM85.rdsp
FINISH
!
! Time-History Post Processing
/POST26
!* Specify the data file where results are to be found
!* TimeHist Postpro>Settings>File  (Set file to VM85.rdsp)
FILE,,rdsp                  ! REDUCED DISPLACEMENTS FILE
!*
!* Specify nodal data to be stored from the results file.
!* Define Variables > Add
NSOL,2,1,U,X  ! ref #, node number, U, x comp
NSOL,3,17,U,X
NSOL,5,9,U,X
!*
!* Math Operations > Add
!* IR=4, FACTA=-1, IA=2, FACTB=1, IB=3
ADD,4,2,3,,REL_DISP,,,-1    ! COMPUTE UX(17) – UX(1)
ADD,6,2,5,,REL_DISP,,,-1    ! COMPUTE UX(9) – UX(1)
!*
!*  TimeHist Postpro>Setings>List (Set Tmin and Tmax)
PRTIME,.053,.057
!* Print the results
!*  TimeHist Postpro>List Variables
PRVAR,2,3,4,5,6
!*
!* Utility Menu>Plot Ctrl > Style > Graphs > Modify Axes
!* Y –axis label = displacements
/AXLAB,Y,DISPLACEMENTS
!* TimeHist Postpro>Graph variables
PLVAR,2,3,4,5,6
!*
!* Math Operations > Derivative
DERIV,7,2,,,1 VX            ! COMPUTE VX(1) = d UX(1)/ dt
DERIV,8,3,,,17VX
DERIV,9,5,,,9 VX
!*
!* Utility Menu>Plot Ctrl > Style > Graphs > Modify Axes
/AXLAB,Y,VELOCITY
!* TimeHist Postpro>Graph variables
PLVAR,7,8,9
FINISH
!* Run the expansion pass and Solve
/SOLU
!* Solution > Analysis Type-Expansion Pass (Set the expansion path on)
!* This step computes stress and others 
!* from displacements for a reduced analysis
EXPASS,ON                   ! EXPANSION PASS
!* Load Step Opts - Expansion Pass > Single Expand-By time /Freq
!* Enter 0.0557 for Time Point
EXPSOL,,,0.0557             ! EXPAND SOLUTION AT TIME CLOSEST TO THE THEORETICAL TIME POINT
!* 
!* Controls the solution printout.
!* Solution>Output Ctrls>Solu Printout (Set FREQ =1 )
OUTPR,,1
!*
SOLVE
FINISH
!*
/POST1
!* Fills a table of element values for further processing
!* General Postproc>Element Table>Define Table>Add
!* Read Results > first set
SET,FIRST
!*   Element Table>Define Table > 
!* Define LS=Line stress data table: No GUI !!!!!
ETABLE,STRS,LS,1
!*  Element Table>List Elem Table>STRS
PRETAB,STRS
!* Plot results>Deformed shape
PLDISP,1
PLDISP,0
!* Animate deformed shape
!* ANDSCL,10,0.1